Convert single document from UI

Use "SwPDFMain"
Sub Click(Source As Button)
    Dim w As New NotesUIWorkspace, doc As NotesDocument
    Dim swPDF As New SwPDFCreator, swPDFDoc As SwPDFDocument, pdfErr As SwPDFError
    Dim DestFilePath As Variant
    
    ' Get destination file path
    DestFilePath = w.SaveFileDialog(False, "Save document", "PDF Files (*.pdf)|*.pdf", "", "test.pdf")
    
    If Not Isempty(DestFilePath)Then
        If Dir$(DestFilePath(0)) <> "" Then
            dialogRes = Messagebox(DestFilePath(0) & " already exists." & Chr$(13) & Chr$(10) & "Do you want to replace it?", 4, "Save document")
            If dialogRes = 7 Then
                Exit Sub
            Else
                Kill DestFilePath(0)
            End If
        End If
        
            ' Procceed with PDF conversion
            ' Get currently opened Notes document
        Set doc = w.CurrentDocument.Document
        
            ' Initialize PDF creation process; license key is required
        If swPDF.Init("<YOUR LICENSE KEY GOES HERE>") Then
                ' enable font embedding for non ascii characters
            swPDF.PDFSettings.EnableFontEmbedding = True
                ' Convert doc to PDF
            Set swPDFDoc = swPDF.ProcessDocument(doc)
            
            If Not swPDFDoc Is Nothing Then
                    ' Finally, save generated PDF to a file on disk
                Call swPDFDoc.SaveToFile(DestFilePath(0))
                
                Msgbox "PDF successfully created in " & DestFilePath(0)
            Else
                    ' There was an error in PDF conversion
                Set pdfErr = swPDF.GetError()
                Msgbox pdfErr.Message, 0+16, "ERROR"
            End If
        Else
                ' There was an error in PDF initialization
            Set pdfErr = swPDF.GetError()
            Msgbox pdfErr.Message, 0+16, "ERROR"
        End If
    End If
End Sub